Working with Rational Engineering Lifecycle Manager

This content needs to be imported to your Engineering Lifecycle Manager project.

How to Install a Content Package

Content packages must be installed on the machine hosting the Rational Engineering Lifecycle Manager server.

How to Deploy the Content Package

Installed content packages are deployed from the administration interface.

To Deploy the artifact elements

How to Create queries

Create the Windchill Queries by following these detailed steps:

# ID: com.sodius.relm.resources.windchill.changerequests.category
# Name
PREFIX oslc_wc: <http://namespaces.sodius.com/windchill/cm/1.0#>
SELECT DISTINCT ?category
WHERE  {
	?resource oslc_wc:category ?category.
} 
ORDER BY ?category
# ID: com.sodius.relm.resources.windchill.changerequests.category
# Name
PREFIX oslc_wc: <http://namespaces.sodius.com/windchill/cm/1.0#>
PREFIX oslc: <http://open-services.net/ns/core#>
PREFIX oslc_cm: <http://open-services.net/ns/cm#>
SELECT DISTINCT ?status
WHERE  {
	?resource oslc_wc:category ?category.
	?resource oslc:serviceProvider ?serviceProvider.
	?resource oslc_cm:status ?status.
} 
ORDER BY ?category
# Name: Windchill Product Change Traceablity
# Parameters:
# 		 Name: allCategories  Type: Boolean Label: 1. Return all Windchill Categories
# 		 Name: wc_category  Type: Enumeration (Windchill Categories) Label: 2. Pick a specific Windchill Category
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX oslc: <http://open-services.net/ns/core#>
PREFIX oslc_cm: <http://open-services.net/ns/cm#>
PREFIX oslc_rtc: <http://jazz.net/xmlns/prod/jazz/rtc/cm/1.0/>
PREFIX oslc_wc: <http://namespaces.sodius.com/windchill/cm/1.0#>

SELECT (?ChangeRequest_shortTitle AS ?ID) 
		?ChangeRequest
		(?wc_category As ?Category)
        (?RelatedSoftwareChangeRequest AS ?Software_CR) 
        (?RelatedTitle AS ?Software_CR_Title)
        (?relatedCrType_rtc AS ?Software_CR_Type)
        (?relatedCrStatus AS ?Software_CR_Status)
WHERE  {
    # Selects only the Change Request provided by the Windchill adapter
    ?ChangeRequest oslc:serviceProvider/dcterms:publisher/dcterms:identifier "com.sodius.windchill" .

	# Get the set of change requests and related counts of software changes
 	{
       SELECT ?ChangeRequest 
               #?ChangeRequest_title 
              (COUNT (?RelatedSoftwareChangeRequest) as ?TotalSCR_Related)
               (SUM (if( !xsd:boolean(?RelatedClosed), 1, 0 ) ) as ?RelatedSCR_OpenCount)
               #(SUM (if( xsd:boolean(?RelatedClosed), 1, 0)) as ?RelatedSCR_ClosedCount)

       WHERE  {
         	 # These two clauses ensure the related change request is an RTC work item
            ?ChangeRequest oslc_cm:relatedChangeRequest ?RelatedSoftwareChangeRequest .
            ?RelatedSoftwareChangeRequest oslc_rtc:type ?relatedCrType_rtc.
 			FILTER ( STRENDS(str(?relatedCrType_rtc), "/defect") )
        
            #?RelatedSoftwareChangeRequest dcterms:title ?RelatedTitle.
            ?RelatedSoftwareChangeRequest oslc_cm:closed ?RelatedClosed.
            #OPTIONAL {?ChangeRequest dcterms:identifier ?dcterms_identifier}
            #OPTIONAL {?RelatedSoftwareChangeRequest dcterms:identifier ?dcterms_RelatedIdentifier}

       } 
       GROUP BY ?ChangeRequest
             #?ChangeRequest_title 
    }       
 		 
    # Remove this if you do not use the Windchill Change Request Category.
    OPTIONAL {?ChangeRequest oslc_wc:category ?wc_category}
	$if(wc_category)$
		FILTER($allCategories$ || str(?wc_category) = "$wc_category$")
	$endif$
	
 	$if(wc_ready)$
    FILTER (!$wc_ready$ ||  ?RelatedSCR_OpenCount = 0 )
	$endif$	
	
	?ChangeRequest oslc:shortTitle ?ChangeRequest_shortTitle.
	?ChangeRequest dcterms:title ?ChangeRequest_title.
        
	# These two clauses ensure the related change request is an RTC work item
	?ChangeRequest oslc_cm:relatedChangeRequest ?RelatedSoftwareChangeRequest.
	?RelatedSoftwareChangeRequest oslc_rtc:type ?relatedCrType_rtc.
	?RelatedSoftwareChangeRequest oslc_cm:status ?relatedCrStatus.
         
	?RelatedSoftwareChangeRequest dcterms:title ?RelatedTitle.
	OPTIONAL {?ChangeRequest oslc_cm:closed ?cr_Closed}
	?RelatedSoftwareChangeRequest oslc_cm:closed ?RelatedClosed.
	#OPTIONAL {?ChangeRequest dcterms:identifier ?dcterms_identifier}
	#OPTIONAL {?RelatedSoftwareChangeRequest dcterms:identifier ?dcterms_RelatedIdentifier}

	FILTER (
		(!bound(?cr_Closed) || !xsd:boolean(?cr_Closed))
	)

} 
ORDER BY ?ChangeRequest_title

then

# Name: Windchill Product Change Traceablity Ready for work
# Parameters:
# 	Name: allCategories  Type: Boolean Label: 1. Return all Windchill Categories
# 	Name: wc_category  Type: Enumeration (Windchill Categories) Label: 2. Pick a specific Windchill Category
# 	Name: wc_ready  Type: Boolean Label: 3. Ready for work
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX oslc: <http://open-services.net/ns/core#>
PREFIX oslc_cm: <http://open-services.net/ns/cm#>
PREFIX oslc_rtc: <http://jazz.net/xmlns/prod/jazz/rtc/cm/1.0/>
PREFIX oslc_wc: <http://namespaces.sodius.com/windchill/cm/1.0#>

SELECT (?ChangeRequest_shortTitle AS ?ID) 
		?ChangeRequest ?wc_category 
		(?TotalSCR_Related AS ?Total_Software_Defects)
		(?RelatedSCR_OpenCount AS ?Open_Software_Defects)
WHERE {
    # Selects only the Change Request provided by the Windchill adapter
    ?ChangeRequest oslc:serviceProvider/dcterms:publisher/dcterms:identifier "com.sodius.windchill" .
         
    # Remove this if you do not use the Windchill Change Request Category.
	?ChangeRequest oslc_wc:category ?wc_category.
	$if(wc_category)$
	FILTER($allCategories$ || str(?wc_category) = "$wc_category$")
	$endif$
	
 	$if(wc_ready)$
    FILTER (!$wc_ready$ ||  ?RelatedSCR_OpenCount = 0 )
	$endif$
        
	?ChangeRequest dcterms:title ?ChangeRequest_title.
	?ChangeRequest oslc:shortTitle ?ChangeRequest_shortTitle.

	OPTIONAL {?ChangeRequest oslc_cm:closed ?cr_Closed}
	
	# Get the set of change requests and related counts of software changes
 	{
       SELECT ?ChangeRequest 
               #?ChangeRequest_title 
              (COUNT (?RelatedSoftwareChangeRequest) as ?TotalSCR_Related)
               (SUM (if( !xsd:boolean(?RelatedClosed), 1, 0 ) ) as ?RelatedSCR_OpenCount)
               #(SUM (if( xsd:boolean(?RelatedClosed), 1, 0)) as ?RelatedSCR_ClosedCount)

       WHERE  {
         	 # These two clauses ensure the related change request is an RTC work item
            ?ChangeRequest oslc_cm:relatedChangeRequest ?RelatedSoftwareChangeRequest .
            ?RelatedSoftwareChangeRequest oslc_rtc:type ?relatedCrType_rtc.
            # We are looking only at defects - not general change requests
  			FILTER ( STRENDS(str(?relatedCrType_rtc), "/defect") )
        
            ?RelatedSoftwareChangeRequest dcterms:title ?RelatedTitle.
            ?RelatedSoftwareChangeRequest oslc_cm:closed ?RelatedClosed.
            
            #OPTIONAL {?ChangeRequest dcterms:identifier ?dcterms_identifier}
            #OPTIONAL {?RelatedSoftwareChangeRequest dcterms:identifier ?dcterms_RelatedIdentifier}

       } 
       GROUP BY ?ChangeRequest
             #?ChangeRequest_title 
    }
    FILTER ( !bound(?cr_Closed) || !xsd:boolean(?cr_Closed)) 
}
ORDER BY ?ChangeRequest_title

then

The content for showing Windchill Change requests should be available in your RELM project. The following sections explain how to use your newly imported content.

Concepts

The set of queries and views included use the concept of software defects and allows you to filter the results of a query based on their states.

Content

Queries

There are four shared queries that you can use to view information about Windchill Change Requests and how they related to software changes tracked in Rational Team Concert. They are located in the Queries section of the Engineering Lifecycle Manager under the Shared Queries tab, in the Windchill Queries folder.

Windchill Change Request Traceabilty: Returns a list of Windchill Change Requests and the related Rational Team Concert work items linked using the RelatedChangeRequests relationship.
Query Parameters:

You may need to make the following customizations to adapt the query to your Windchill deployment:

Windchill Change Request Traceabilty Rollup: Returns a list of Windchill Change Requests and the counts of related Rational Team Concert work items linked using the RelatedChangeRequests relationship. This query is identical to the “Windchill Change Request Traceability� query, except that it shows aggregated counts instead of each related software change request.
Query Parameters:

You may need to make the following customizations to adapt the query to your Windchill deployment:

Windchill Category Enumeration: You can use this query to list the category values of all Windchill Change Requests. Be aware that it won’t show values for any categories RELM has not seen. It’s a convenient query you can use to make sure you have the correct values for the “Windchill Categories� enumeration used by the two traceability rollup queries.
Windchill Status Enumeration: You can use this query to list the status values of all Windchill Change Requests. Be aware that it won’t show values for any categories RELM has not seen. It’s a convenient query you can use to make sure you have the correct values for the states parameter values used in views.

Artifact Element Queries

There are two artifact element queries used to create Views showing Windchill Change Requests. These are located in the Windchill Artifact Elements folder. Each query shows the connections between the two systems, starting from each side.

WindchillChangeRequest: Selects a set of Windchill Change Requests and the related to Rational Team Concert work items.
Software Change Request: Selects a set of Rational Team Concert work items and the related Windchill Change Requests.

Views

A number of pre-built views are included as examples. They are located under Shared Views in the Windchill Views folder. The equivalent of views can quickly be built starting with the Artifact Element Queries. Once you get the hang of how to configure the query parameters, you may want to create your own views or modify the samples to fit your specific needs.
All Windchill Change Requests: Returns an unfiltered set of Windchill Change Requests and all related Rational Team Concert work items.
All Windchill Change Requests with Software Changes: Limits the set of Windchill Change Requests by checking the “Related CRs only� parameter on the Windchill Change Request.
Open Windchill Change Requests with Software Changes: Further restricts the “All Windchill Change Requests with Software Changes� view by checking the “Open CRs only� parameter, in addition to the other settings.
Open Windchill Change Requests with Completed Software Changes: Further restricts the “Open Windchill Change Requests with Software Changes� view by checking the “Software defects complete� parameter, in addition to the other settings.
Open Windchill Product Improvements with Software Changes: Further restricts the “Open Windchill Change Requests with Software Changes� view specifying “PRODUCT_IMPROVEMENT� as the Windchill Change Request Category on the Windchill Change Request, in addition to the other settings.
Open Windchill Product Improvements with Open Software Changes: Further restricts the “Open Windchill Product Improvements with Software Changes� view by checking the “Software defects open� parameter, in addition to the other settings.
Open Windchill Product Improvements with Completed Software Changes: Further restricts the “Open Windchill Product Improvements with Software Changes� view by checking the “Software defects complete� parameter, in addition to the other settings.

References

This is the location of the IBM Knowledge Center documentation on deploying content packages:
http://www-01.ibm.com/support/knowledgecenter/SS2L6K_5.0.1/com.ibm.rational.relm.doc/topics/c_deploycontentpack.html?lang=en
There is also a supplemental article on jazz.net that explains how to install content packages on a RELM server: https://jazz.net/library/article/1012